gsm-fw/gpf/conf/gsmcomp.c: increased max partition in the voice-only config The code we got from TCS211 had the maximum prim pool partition size set to 900 bytes in the voice-only config (no FAX_AND_DATA, no GPRS) and to 1600 bytes in every other config. As it turns out, this "minimized" config breaks when the AT command interface is used with %CPI enabled, as the responsible code in ATI does an ACI_MALLOC of 1012 bytes. TI may have considered this case to be unsupported usage (perhaps they didn't care about the combination of a voice-only PS with AT command control), but we do want this use case to work without crashing. Solution: I made the largest prim pool the same as it is with FAX_AND_DATA: 3 partitions of 1600 bytes.

#include "ns16550.h"

@ this module implements the elementary serial I/O operations

	.text
	.code	32
	.global	serial_out
serial_out:
	ldr	r1, =uart_base
	ldr	r2, [r1]
1:	ldrb	r3, [r2, #NS16550_LSR]
	tst	r3, #NS16550_LSR_THRE
	beq	1b
	strb	r0, [r2, #NS16550_THR]
	bx	lr

	.global	serial_in_poll
serial_in_poll:
	ldr	r1, =uart_base
	ldr	r2, [r1]
	ldrb	r3, [r2, #NS16550_LSR]
	tst	r3, #NS16550_LSR_DR
	ldrneb	r0, [r2, #NS16550_RBR]
	mvneq	r0, #0
	bx	lr

	.global	serial_flush
serial_flush:
	ldr	r1, =uart_base
	ldr	r2, [r1]
1:	ldrb	r3, [r2, #NS16550_LSR]
	tst	r3, #NS16550_LSR_TEMP
	beq	1b
	bx	lr