rvinterf/etmsync/fsnew.c: cast 0 to (char *) for execl sentinel I generally don't use NULL and use plain 0 instead, based on a "NULL considered harmful" discussion on the classiccmp mailing list many aeons ago (I couldn't find it, and I reason that it must have been 2005 or earlier), but a recent complaint by a packager sent me searching, and I found this: https://ewontfix.com/11/ While I don't give a @#$% about "modern" systems and code-nazi tools, I realized that passing a plain 0 as a pointer sentinel in execl is wrong because it will break on systems where pointers are longer than the plain int type. Again, I don't give a @#$% about the abomination of x86_64 and the like, but if anyone ever manages to port my code to something like a PDP-11 (16-bit int, 32-bit long and pointers), then passing a plain 0 as a function argument where a pointer is expected most definitely won't work: if the most natural stack slot and SP alignment unit is 16 bits, fitting an int, with longs and pointers taking up two such slots, then the call stack will be totally wrong with a plain 0 passed for a pointer. Casting the 0 to (char *) ought to be the most kosher solution for the most retro systems possible.

	.text
	.org	0

@ allow entry in Thumb state
	.code	16
	bx	pc
	nop

	.code	32

@ set CPSR like mot931c payload does
	msr	CPSR_c, #0xd3
@ disable the watchdog
	ldr	r1, =0xfffff802
	mov	r0, #0xf5
	strh	r0, [r1, #2]
	mov	r0, #0xa0
	strh	r0, [r1, #2]
@ MODEM UART
	ldr	r6, =0xffff5800
@ wait for any previous output to flush out
1:	ldrb	r0, [r6, #5]
	tst	r0, #0x20
	beq	1b
@ send our indication
	adr	r1, outstr
	mov	r2, #6
1:	ldrb	r0, [r1], #1
	strb	r0, [r6]
	subs	r2, r2, #1
	bne	1b
@ wait for this output to go out to the TxD pin
1:	ldrb	r0, [r6, #5]
	tst	r0, #0x40
	beq	1b
@ enable the Calypso boot ROM
	ldr	r1, =0xFFFFFB10
	mov	r2, #0x0100
	strh	r2, [r1]
@ jump to it!
	mov	pc, #0
	.ltorg
outstr:	.byte	2,2,2,'O','K',2