view target-utils/libbase/serio.S @ 965:2969032bdfac

fcup-smsend[mult]: fix buglet in K&R C NULL pointer passing The only 100% safe way to pass a NULL pointer as a function argument in K&R C is to cast 0 to a pointer type; failing to do so may cause mysterious bugs (invalid stack frames or garbage in argument registers) on 64-bit machines. This issue has already been fixed in most of FC host tools, but I just found some missed spots: passing of NULL UDH to PDU encoding functions in fcup-smsend[mult] in the case of single (not concatenated) SMS.
author Mychaela Falconia <falcon@freecalypso.org>
date Fri, 01 Sep 2023 07:33:51 +0000
parents da6df2c626cf
children
line wrap: on
line source

#include "ns16550.h"

@ this module implements the elementary serial I/O operations

	.comm	uart_base,4,4

	.text
	.code	32
	.global	serial_out
serial_out:
	ldr	r1, =uart_base
	ldr	r2, [r1]
1:	ldrb	r3, [r2, #0x11]		@ Calypso UART non-std register SSR
	tst	r3, #0x01		@ Tx FIFO full flag
	bne	1b
	strb	r0, [r2, #NS16550_THR]
	bx	lr

	.global	serial_in_poll
serial_in_poll:
	ldr	r1, =uart_base
	ldr	r2, [r1]
	ldrb	r3, [r2, #NS16550_LSR]
	tst	r3, #NS16550_LSR_DR
	ldrneb	r0, [r2, #NS16550_RBR]
	mvneq	r0, #0
	bx	lr

	.global	serial_flush
serial_flush:
	ldr	r1, =uart_base
	ldr	r2, [r1]
1:	ldrb	r3, [r2, #NS16550_LSR]
	tst	r3, #NS16550_LSR_TEMP
	beq	1b
	bx	lr