FreeCalypso > hg > tcs211-pirelli

comparison gpf/util/sape/xslt/pdf-mdf/PDF-MDF-common.xsl @ 0:509db1a7b7b8

Find changesets by keywords (author, files, the commit message), revision number or hash, or revset expression.
initial import: leo2moko-r1
author Space Falcon <falcon@ivan.Harhan.ORG>
date Mon, 01 Jun 2015 03:24:05 +0000
parents
children
comparison
equal deleted inserted replaced
-1:000000000000 0:509db1a7b7b8
1 <?xml version="1.0" encoding="UTF-8"?>
2 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:ext-pack="xalan://com.ti.xslt.extension" extension-element-prefixes="ext-pack">
3 <xsl:import href="../format.xsl"/>
4 <xsl:import href="../getExternType.xsl"/>
5 <xsl:import href="../date.xsl"/>
6 <xsl:import href="../docID.xsl"/>
7 <!-- asn1-fix
8 0: no fix
9 1: print range after valType ref to avoid ccdgen crash when calulating per bit size
10 2: eleminate valType to avoid ccdgen generating BUF types for ASN1_INTEGER > 24bit
11 -->
12 <xsl:param name="asn1-fix" select="0"/>
13 <xsl:output method="text"/>
14 <!--DocInfoSection template: A header for the output file will be created. The content is pretty much the same for all different type of output files. Some adjustments have to be made to support the comment rules for the C language. Besides that the transformantion is simple and straight forward.-->
15 <xsl:template match="DocInfoSection">
16 <xsl:param name="output"/>
17 <xsl:if test="$output='C'">
18 <xsl:text>/***</xsl:text>
19 <xsl:value-of select="$newline"/>
20 </xsl:if>
21 <xsl:value-of select="$line"/>
22 <!--print out the name of the output file-->
23 <xsl:value-of select="$comment"/>
24 <xsl:text>File : </xsl:text>
25 <xsl:value-of select="./DocName"/>
26 <xsl:choose>
27 <xsl:when test="$output='PDF'">
28 <xsl:text>.pdf</xsl:text>
29 </xsl:when>
30 <xsl:when test="$output='MDF'">
31 <xsl:text>.mdf</xsl:text>
32 </xsl:when>
33 <xsl:when test="$output='C'">
34 <xsl:text>_inline.h</xsl:text>
35 </xsl:when>
36 </xsl:choose>
37 <xsl:value-of select="$newline"/>
38 <!--print out the date and time of creation-->
39 <xsl:value-of select="$comment"/>
40 <xsl:text>Creation : </xsl:text>
41 <!--use customized java class of extension packet to get date and time-->
42 <xsl:value-of select="ext-pack:CurrentDate.getCurrentDate( )"/>
43 <xsl:value-of select="$newline"/>
44 <!--print out the vendor, url and xslt version of the used XSLT processor-->
45 <xsl:value-of select="$comment"/>
46 <xsl:text>XSLT Processor : </xsl:text>
47 <xsl:value-of select="system-property('xsl:vendor')"/>
48 <xsl:text> / </xsl:text>
49 <xsl:value-of select="system-property('xsl:vendor-url')"/>
50 <xsl:text> / supports XSLT-Ver: </xsl:text>
51 <xsl:value-of select="system-property('xsl:version')"/>
52 <xsl:value-of select="$newline"/>
53 <!--print out copyright notice-->
54 <xsl:value-of select="$comment"/>
55 <xsl:text>Copyright : (c) Texas Instruments AG, Berlin Germany 2002</xsl:text>
56 <xsl:value-of select="$newline"/>
57 <xsl:value-of select="$line"/>
58 <!--print out document type-->
59 <xsl:value-of select="$comment"/>
60 <xsl:text>Document Type : </xsl:text>
61 <xsl:choose>
62 <xsl:when test='./DocName/@DocType="SAP"'>
63 <xsl:text>Service Access Point Specification</xsl:text>
64 </xsl:when>
65 <xsl:when test='./DocName/@DocType="AIM"'>
66 <xsl:text>Air Interface Message Specification</xsl:text>
67 </xsl:when>
68 </xsl:choose>
69 <xsl:value-of select="$newline"/>
70 <!--print out document name-->
71 <xsl:value-of select="$comment"/>
72 <xsl:text>Document Name : </xsl:text>
73 <xsl:value-of select="./DocName"/>
74 <xsl:value-of select="$newline"/>
75 <!--print out document number, document date, status and author-->
76 <xsl:for-each select="./DocHistory">
77 <xsl:if test="position()=last()">
78 <xsl:value-of select="$comment"/>
79 <xsl:text>Document No. : </xsl:text>
80 <xsl:apply-templates select="." mode="DocID"/>
81 <xsl:value-of select="$newline"/>
82 <!--print out document date-->
83 <xsl:value-of select="$comment"/>
84 <xsl:text>Document Date : </xsl:text>
85 <xsl:apply-templates select="./Date"/>
86 <xsl:value-of select="$newline"/>
87 <!--print out document status-->
88 <xsl:value-of select="$comment"/>
89 <xsl:text>Document Status: </xsl:text>
90 <xsl:value-of select="./DocStatus/@State"/>
91 <xsl:value-of select="$newline"/>
92 <!--print out author-->
93 <xsl:value-of select="$comment"/>
94 <xsl:text>Document Author: </xsl:text>
95 <xsl:value-of select="./Author"/>
96 <xsl:value-of select="$newline"/>
97 </xsl:if>
98 </xsl:for-each>
99 <xsl:value-of select="$line"/>
100 <xsl:if test="$output='C'">
101 <xsl:value-of select="$comment"/>
102 <xsl:text>!!! THIS INCLUDE FILE WAS GENERATED AUTOMATICALLY, DO NOT MODIFY !!!</xsl:text>
103 <xsl:value-of select="$newline"/>
104 <xsl:value-of select="$line"/>
105 <xsl:text> ***/</xsl:text>
106 <xsl:value-of select="$newline"/>
107 </xsl:if>
108 </xsl:template>
109 <!--Pragma template: for all Pragma elements of the PragmasSection, assemble PDF representation-->
110 <xsl:template match="Pragma">
111 <xsl:text>PRAGMA</xsl:text>
112 <xsl:value-of select="$delimiter"/>
113 <xsl:value-of select="./Name"/>
114 <xsl:value-of select="$delimiter"/>
115 <xsl:call-template name="getValPrefix">
116 <xsl:with-param name="valType" select="./Value/@ValueType"/>
117 </xsl:call-template>
118 <xsl:value-of select="./Value"/>
119 <xsl:value-of select="$delimiter"/>
120 <xsl:text>; </xsl:text>
121 <xsl:call-template name="stripComment">
122 <xsl:with-param name="str" select="./Comment"/>
123 </xsl:call-template>
124 <xsl:value-of select="$newline"/>
125 </xsl:template>
126 <!--Constant template: for all Constant elements of the ConstantsSection, assemble PDF representation-->
127 <xsl:template match="Constant">
128 <xsl:choose>
129 <xsl:when test="./Value">
130 <xsl:text>CONST</xsl:text>
131 <xsl:value-of select="$delimiter"/>
132 <xsl:value-of select="./Alias"/>
133 <xsl:value-of select="$delimiter"/>
134 <xsl:call-template name="getValPrefix">
135 <xsl:with-param name="valType" select="./Value/@ValueType"/>
136 </xsl:call-template>
137 <xsl:value-of select="./Value"/>
138 </xsl:when>
139 <xsl:when test="./ItemLink">
140 <xsl:text>EXTERN CONST</xsl:text>
141 <xsl:value-of select="$delimiter"/>
142 <xsl:for-each select="./ItemLink">
143 <xsl:call-template name="assembleLink"/>
144 </xsl:for-each>
145 <xsl:value-of select="./Alias"/>
146 </xsl:when>
147 </xsl:choose>
148 <xsl:apply-templates select="./Version"/>
149 <xsl:value-of select="$delimiter"/>
150 <xsl:text>; </xsl:text>
151 <xsl:call-template name="stripComment">
152 <xsl:with-param name="str" select="./Comment"/>
153 </xsl:call-template>
154 <xsl:value-of select="$newline"/>
155 <xsl:for-each select="./Group">
156 <xsl:call-template name="setGroup"/>
157 </xsl:for-each>
158 </xsl:template>
159 <!--ValuesLink template: Definition is simple and straight forward.-->
160 <xsl:template match="ValuesLink">
161 <xsl:text>VAL</xsl:text>
162 <xsl:value-of select="$delimiter"/>
163 <xsl:call-template name="assembleLink"/>
164 </xsl:template>
165 <!--Values template: First line will be the declaration of the values table with keyword VALTAB and Name. In case a range is defined for the values table, it will be transformed first. After that all value definitions will be transformed to PDF-->
166 <xsl:template match="Values">
167 <xsl:param name="output"/>
168 <xsl:if test="$asn1-fix!=2">
169 <xsl:text>VALTAB</xsl:text>
170 <xsl:value-of select="$delimiter"/>
171 <xsl:value-of select="./ValuesDef/Name"/>
172 <xsl:if test="./ValuesDef/Alias">
173 <xsl:value-of select="$delimiter"/>
174 <xsl:text>AS </xsl:text>
175 <xsl:value-of select="./ValuesDef/Alias"/>
176 </xsl:if>
177 <xsl:apply-templates select="./ValuesDef/Version"/>
178 <xsl:value-of select="$newline"/>
179 <xsl:for-each select="./ValuesDef/Group">
180 <xsl:call-template name="setGroup"/>
181 </xsl:for-each>
182 <xsl:apply-templates select="." mode="Values-elements">
183 <xsl:with-param name="output" select="$output"/>
184 </xsl:apply-templates>
185 </xsl:if>
186 </xsl:template>
187 <xsl:template match="Values" mode="Values-elements">
188 <xsl:param name="output"/>
189 <xsl:for-each select="./ValuesRange">
190 <xsl:choose>
191 <xsl:when test="$output='PDF'">
192 <xsl:text>VAL</xsl:text>
193 <xsl:value-of select="$delimiter"/>
194 <xsl:call-template name="getValPrefix">
195 <xsl:with-param name="valType" select="./@ValueType"/>
196 </xsl:call-template>
197 <xsl:value-of select="./MinValue"/>
198 <xsl:text> - </xsl:text>
199 <xsl:call-template name="getValPrefix">
200 <xsl:with-param name="valType" select="./@ValueType"/>
201 </xsl:call-template>
202 <xsl:value-of select="./MaxValue"/>
203 <xsl:value-of select="$delimiter"/>
204 <xsl:if test="./Alias">
205 <xsl:value-of select="./Alias"/>
206 <xsl:value-of select="$delimiter"/>
207 </xsl:if>
208 <xsl:text>"</xsl:text>
209 <xsl:call-template name="stripComment">
210 <xsl:with-param name="str" select="./Comment"/>
211 </xsl:call-template>
212 <xsl:text>"</xsl:text>
213 </xsl:when>
214 <xsl:when test="$output='MDF'">
215 <xsl:text>RANGE</xsl:text>
216 <xsl:value-of select="$delimiter"/>
217 <xsl:call-template name="getValPrefix">
218 <xsl:with-param name="valType" select="./@ValueType"/>
219 </xsl:call-template>
220 <xsl:value-of select="./MinValue"/>
221 <xsl:text> .. </xsl:text>
222 <xsl:call-template name="getValPrefix">
223 <xsl:with-param name="valType" select="./@ValueType"/>
224 </xsl:call-template>
225 <xsl:value-of select="./MaxValue"/>
226 <xsl:if test="$asn1-fix!=2">
227 <xsl:value-of select="$delimiter"/>
228 <xsl:text>"</xsl:text>
229 <xsl:call-template name="stripComment">
230 <xsl:with-param name="str" select="./Comment"/>
231 </xsl:call-template>
232 <xsl:text>"</xsl:text>
233 </xsl:if>
234 </xsl:when>
235 </xsl:choose>
236 <xsl:value-of select="$newline"/>
237 </xsl:for-each>
238 <xsl:if test="./ValuesDefault">
239 <xsl:choose>
240 <xsl:when test="$output='PDF'">
241 <xsl:if test="./ValuesDefault/Value">
242 <xsl:message terminate="no">
243 <xsl:call-template name="cmdLineMsg">
244 <xsl:with-param name="msgType" select="warning"/>
245 <xsl:with-param name="msg">
246 <xsl:text>A default value is defined, but could not be considered for PDF format!</xsl:text>
247 </xsl:with-param>
248 </xsl:call-template>
249 </xsl:message>
250 </xsl:if>
251 <xsl:text>VAL</xsl:text>
252 <xsl:value-of select="$delimiter"/>
253 <xsl:text>DEF</xsl:text>
254 <xsl:value-of select="$delimiter"/>
255 </xsl:when>
256 <xsl:when test="$output='MDF'">
257 <xsl:choose>
258 <xsl:when test="./ValuesDefault/Value">
259 <xsl:text>IFNOTPRESENT </xsl:text>
260 <xsl:value-of select="./ValuesDefault/Value"/>
261 </xsl:when>
262 <xsl:otherwise>
263 <xsl:text>VAL</xsl:text>
264 <xsl:value-of select="$delimiter"/>
265 <xsl:text>DEF</xsl:text>
266 <xsl:value-of select="$delimiter"/>
267 </xsl:otherwise>
268 </xsl:choose>
269 </xsl:when>
270 </xsl:choose>
271 <xsl:if test="not($output='MDF' and ./ValuesDefault/Value)">
272 <xsl:value-of select="$delimiter"/>
273 <xsl:text>"</xsl:text>
274 <xsl:call-template name="stripComment">
275 <xsl:with-param name="str" select="./ValuesDefault/Comment"/>
276 </xsl:call-template>
277 <xsl:text>"</xsl:text>
278 </xsl:if>
279 <xsl:value-of select="$newline"/>
280 </xsl:if>
281 <xsl:for-each select="./ValuesItem">
282 <xsl:text>VAL</xsl:text>
283 <xsl:value-of select="$delimiter"/>
284 <xsl:choose>
285 <xsl:when test="./Value and ./Value!=''">
286 <xsl:call-template name="getValPrefix">
287 <xsl:with-param name="valType" select="./Value/@ValueType"/>
288 </xsl:call-template>
289 <xsl:value-of select="./Value"/>
290 </xsl:when>
291 <xsl:otherwise>
292 <xsl:text>*</xsl:text>
293 </xsl:otherwise>
294 </xsl:choose>
295 <xsl:value-of select="$delimiter"/>
296 <xsl:value-of select="./Alias"/>
297 <xsl:apply-templates select="./Version"/>
298 <xsl:value-of select="$delimiter"/>
299 <xsl:text>"</xsl:text>
300 <xsl:call-template name="stripComment">
301 <xsl:with-param name="str" select="./Comment"/>
302 </xsl:call-template>
303 <xsl:text>"</xsl:text>
304 <xsl:value-of select="$newline"/>
305 </xsl:for-each>
306 <xsl:value-of select="$newline"/>
307 </xsl:template>
308 <!--Version template:This template creates the declaration of a feature flag-->
309 <xsl:template match="Version">
310 <xsl:value-of select="$delimiter"/>
311 <xsl:text>%</xsl:text>
312 <xsl:value-of select="."/>
313 <xsl:text>%</xsl:text>
314 </xsl:template>
315 <!--ItemLink template: ItemLink elements will only be processed, if the link points to an external document (DocName of ItemLink is different from DocName of the DocInfoSection). Definition is simple and straight forward.-->
316 <xsl:template match="ItemLink" mode="typedef">
317 <!--to get the type of the external element (old MDF/PDF format) call template getExternType with elemName = ./Name, docName=./DocName, docType=./DocName/@DocType-->
318 <xsl:call-template name="assembleLink"/>
319 </xsl:template>
320 <xsl:template match="ItemLink">
321 <!--If ItemLink references an internal link (same document), then omit the link syntax for now, until ccdGen is extended.-->
322 <xsl:if test="./DocName != /*/DocInfoSection/DocName">
323 <xsl:text>EXTERN </xsl:text>
324 <!--to get the type of the external element (old MDF/PDF format) call template getExternType with elemName = ./Name, docName=./DocName, docType=./DocName/@DocType-->
325 <xsl:call-template name="assembleLink"/>
326 </xsl:if>
327 </xsl:template>
328 <!--Substitute template:This template creates the definition for a substitution-->
329 <xsl:template match="Substitute">
330 <xsl:text>TYPEDEF</xsl:text>
331 <xsl:value-of select="$delimiter"/>
332 <xsl:call-template name="getExternType">
333 <xsl:with-param name="elemName" select="./ItemLink/Name"/>
334 <xsl:with-param name="docType" select="./ItemLink/DocName/@DocType"/>
335 <xsl:with-param name="docName" select="./ItemLink/DocName"/>
336 <xsl:with-param name="transformType" select="'varOnly'"/>
337 </xsl:call-template>
338 <xsl:value-of select="$delimiter"/>
339 <xsl:choose>
340 <!--If ItemLink references an internal link (same document), then omit the link syntax for now, until ccdGen is extended.-->
341 <xsl:when test="./ItemLink/DocName != /*/DocInfoSection/DocName">
342 <xsl:for-each select="./ItemLink">
343 <xsl:call-template name="assembleLink"/>
344 </xsl:for-each>
345 </xsl:when>
346 <xsl:otherwise>
347 <xsl:value-of select="./ItemLink/Name"/>
348 </xsl:otherwise>
349 </xsl:choose>
350 <xsl:value-of select="$delimiter"/>
351 <xsl:value-of select="./Alias"/>
352 <xsl:apply-templates select="./Version"/>
353 <xsl:value-of select="$delimiter"/>
354 <xsl:text>"</xsl:text>
355 <xsl:call-template name="stripComment">
356 <xsl:with-param name="str" select="./Comment"/>
357 </xsl:call-template>
358 <xsl:text>"</xsl:text>
359 <xsl:value-of select="$newline"/>
360 </xsl:template>
361 <!--named template to add the group name-->
362 <xsl:template name="setGroup">
363 <xsl:value-of select="$delimiter"/>
364 <xsl:text>GROUP </xsl:text>
365 <xsl:value-of select="."/>
366 <xsl:value-of select="$newline"/>
367 </xsl:template>
368 <!--named template to assemble a link description in PDF-->
369 <xsl:template name="assembleLink">
370 <xsl:choose>
371 <xsl:when test='./DocName[@DocType="SAP"]'>
372 <xsl:text>@p_</xsl:text>
373 </xsl:when>
374 <xsl:when test='./DocName[@DocType="AIM"]'>
375 <xsl:text>@m_</xsl:text>
376 </xsl:when>
377 <xsl:otherwise>
378 <xsl:message terminate="yes">
379 <xsl:call-template name="cmdLineMsg">
380 <xsl:with-param name="msgType" select="error"/>
381 <xsl:with-param name="msg">
382 <xsl:text>DocName@DocType is neither SAP nor AIM</xsl:text>
383 </xsl:with-param>
384 </xsl:call-template>
385 </xsl:message>
386 </xsl:otherwise>
387 </xsl:choose>
388 <xsl:value-of select="./DocName"/>
389 <xsl:text> - </xsl:text>
390 <xsl:value-of select="./Name"/>
391 <xsl:text>@</xsl:text>
392 <xsl:value-of select="$delimiter"/>
393 </xsl:template>
394 <!--named template to assemble the definition of a structured element-->
395 <xsl:template name="StructElemDef">
396 <xsl:choose>
397 <xsl:when test='./@Type="UNION"'>
398 <xsl:text>UNION</xsl:text>
399 </xsl:when>
400 <xsl:otherwise>
401 <xsl:text>COMP</xsl:text>
402 </xsl:otherwise>
403 </xsl:choose>
404 <xsl:value-of select="$delimiter"/>
405 <xsl:value-of select="./Name"/>
406 <xsl:apply-templates select="./Version"/>
407 <xsl:value-of select="$delimiter"/>
408 <xsl:text>"</xsl:text>
409 <xsl:call-template name="stripComment">
410 <xsl:with-param name="str" select="./Comment"/>
411 </xsl:call-template>
412 <xsl:text>"</xsl:text>
413 <xsl:value-of select="$newline"/>
414 <xsl:for-each select="./Group">
415 <xsl:call-template name="setGroup"/>
416 </xsl:for-each>
417 </xsl:template>
418 <!--named template extract relevant text for PDF/MDF comments-->
419 <xsl:template name="stripComment">
420 <xsl:param name="str"/>
421 <xsl:variable name="dblQts">
422 <xsl:text>"</xsl:text>
423 </xsl:variable>
424 <xsl:variable name="sglQts">
425 <xsl:text>'</xsl:text>
426 </xsl:variable>
427 <xsl:choose>
428 <xsl:when test="contains($str,$dblQts)">
429 <!--exchange double quotes with single quotes-->
430 <xsl:value-of select="translate($str, $dblQts, $sglQts )"/>
431 </xsl:when>
432 <xsl:otherwise>
433 <xsl:value-of select="$str"/>
434 </xsl:otherwise>
435 </xsl:choose>
436 </xsl:template>
437 <!--named template add file status pragmas-->
438 <xsl:template name="fileStatPragmas">
439 <xsl:variable name="fileName">
440 <xsl:choose>
441 <xsl:when test="*/DocInfoSection/DocName/@DocType = 'SAP'">
442 <xsl:value-of select="concat($absSapPath,*/DocInfoSection/DocName,'.sap')"/>
443 </xsl:when>
444 <xsl:otherwise>
445 <xsl:value-of select="concat($absAimPath,*/DocInfoSection/DocName,'.aim')"/>
446 </xsl:otherwise>
447 </xsl:choose>
448 </xsl:variable>
449 <xsl:value-of select="concat('PRAGMA',$delimiter,'SRC_FILE_TIME')"/>
450 <xsl:value-of select="$delimiter"/>
451 <xsl:text>"</xsl:text>
452 <xsl:value-of select="ext-pack:FileDate.getFileDate($fileName )"/>
453 <xsl:text>"</xsl:text>
454 <xsl:value-of select="$newline"/>
455 <xsl:for-each select="*/DocInfoSection/DocHistory">
456 <xsl:if test="position()=last()">
457 <xsl:value-of select="concat('PRAGMA',$delimiter,'LAST_MODIFIED')"/>
458 <xsl:value-of select="$delimiter"/>
459 <xsl:text>"</xsl:text>
460 <xsl:apply-templates select="./Date"/>
461 <xsl:text>"</xsl:text>
462 <xsl:value-of select="$newline"/>
463 <xsl:value-of select="concat('PRAGMA',$delimiter,'ID_AND_VERSION')"/>
464 <xsl:value-of select="$delimiter"/>
465 <xsl:text>"</xsl:text>
466 <xsl:apply-templates select="." mode="DocID"/>
467 <xsl:text>"</xsl:text>
468 <xsl:value-of select="$newline"/>
469 </xsl:if>
470 </xsl:for-each>
471 </xsl:template>
472 </xsl:stylesheet>